fixes, fog experiments, add shaders to tree

shaders/blinnphong.frag

@@ -0,0 +1,111 @@
+#version 330
+
+const uint LIGHT_SPOT = 0U;
+const uint LIGHT_POINT = 1U;
+const uint LIGHT_DIR = 2U;
+
+struct light_s
+{
+	uint type;
+
+	vec3 pos;
+	vec3 dir;
+	
+	float in_cutoff;
+	float out_cutoff;
+
+	vec3 color;
+	
+	float linear;
+	float quadratic;
+};
+
+in vec3 f_normal;
+in vec2 f_coord;
+in vec3 f_pos;
+
+out vec4 color;
+
+uniform sampler2D tex;
+
+uniform vec3 ambient;
+uniform vec3 emission;
+uniform vec3 fog_color;
+uniform float fog_density;
+uniform float specular;
+
+uniform light_s lights[8];
+uniform uint lights_count;
+
+vec3 apply_fog(vec3 color)
+{
+	float sun_amount = 0.0;
+	if (lights_count >= 1U && lights[0].type == LIGHT_DIR)
+		sun_amount = max(dot(normalize(f_pos), normalize(-lights[0].dir)), 0.0);
+	vec3 fog_color_v = mix(fog_color, lights[0].color, pow(sun_amount, 30.0));
+	float fog_amount_v = 1.0 - min(1.0, exp(-length(f_pos) * fog_density));
+	return mix(color, fog_color_v, fog_amount_v);
+}
+
+float calc_light(vec3 light_dir)
+{
+	vec3 normal = normalize(f_normal);
+	vec3 view_dir = normalize(vec3(0.0f, 0.0f, 0.0f) - f_pos);
+	vec3 halfway_dir = normalize(light_dir + view_dir);
+	
+	float diffuse_v = max(dot(normal, light_dir), 0.0);
+	float specular_v = pow(max(dot(normal, halfway_dir), 0.0), 15.0) * specular;
+	
+	return specular_v + diffuse_v;
+}
+
+float calc_point_light(light_s light)
+{
+	vec3 light_dir = normalize(light.pos - f_pos);
+	float val = calc_light(light_dir);
+	
+	float distance = length(light.pos - f_pos);
+	float atten = 1.0f / (1.0f + light.linear * distance + light.quadratic * (distance * distance));
+	
+	return val * atten;
+}
+
+float calc_spot_light(light_s light)
+{
+	vec3 light_dir = normalize(light.pos - f_pos);
+	
+	float theta = dot(light_dir, normalize(-light.dir));
+	float epsilon = light.in_cutoff - light.out_cutoff;
+	float intensity = clamp((theta - light.out_cutoff) / epsilon, 0.0, 1.0);
+
+	float point = calc_point_light(light);	
+	return point * intensity;
+}
+
+float calc_dir_light(light_s light)
+{
+	vec3 light_dir = normalize(-light.dir);
+	return calc_light(light_dir);
+}
+
+void main()
+{
+	vec3 result = ambient * 0.3 + emission;
+	for (uint i = 0U; i < lights_count; i++)
+	{
+		light_s light = lights[i];
+		float part = 0.0;
+		
+		if (light.type == LIGHT_SPOT)
+			part = calc_spot_light(light);
+		else if (light.type == LIGHT_POINT)
+			part = calc_point_light(light);
+		else if (light.type == LIGHT_DIR)
+			part = calc_dir_light(light);
+		
+		result += light.color * part;
+	}
+	
+	vec4 tex_color = texture(tex, f_coord);	
+	color = vec4(apply_fog(result * tex_color.xyz), tex_color.w);
+}

shaders/color.frag

@@ -0,0 +1,10 @@
+#version 330
+
+in vec3 f_color;
+
+out vec4 color;
+
+void main()
+{
+	color = vec4(f_color, 1.0f);
+}

shaders/lighting.vert

@@ -0,0 +1,21 @@
+#version 330
+
+layout (location = 0) in vec3 v_vert;
+layout (location = 1) in vec3 v_normal;
+layout (location = 2) in vec2 v_coord;
+
+out vec3 f_normal;
+out vec2 f_coord;
+out vec3 f_pos;
+
+uniform mat4 modelview;
+uniform mat3 modelviewnormal;
+uniform mat4 projection;
+
+void main()
+{
+	gl_Position = (projection * modelview) * vec4(v_vert, 1.0f);
+	f_normal = modelviewnormal * v_normal;
+	f_coord = v_coord;
+	f_pos = vec3(modelview * vec4(v_vert, 1.0f));
+}

shaders/vbocolor.vert

@@ -0,0 +1,15 @@
+#version 330
+
+layout (location = 0) in vec3 v_vert;
+layout (location = 1) in vec3 v_color;
+
+out vec3 f_color;
+
+uniform mat4 modelview;
+uniform mat4 projection;
+
+void main()
+{
+	gl_Position = projection * modelview * vec4(v_vert, 1.0f);
+	f_color = v_color;
+}